| 常量 | 常量值 | 说明 |
| vbOKOnly | 0 | 只显示“确定”按钮（缺省值） |
| VbOKCancel | 1 | 显示“确定”和“取消”按钮 |
| VbAbortRetryIgnore | 2 | 显示“终止”、“重试”和“忽略” 按钮 |
| VbYesNoCancel | 3 | 显示“是”、“否”和“取消”按钮 |
| VbYesNo | 4 | 显示“是”和“否”按钮 |
| VbRetryCancel | 5 | 显示“重试”和“取消”按钮 |
| VbCritical | 16 | 显示“错误信息”图标 |
| VbQuestion | 32 | 显示“问号”图标 |
| VbExclamation | 48 | 显示“警告消息”图标 |
| VbInformation | 64 | 显示“通知消息”图标 |
| vbDefaultButton1 | 0 | 第一个按钮是缺省值（缺省设置） |
| vbDefaultButton2 | 256 | 第二个按钮是缺省值 |
| vbDefaultButton3 | 512 | 第三个按钮是缺省值 |
| vbDefaultButton4 | 768 | 第四个按钮是缺省值 |
| vbApplicationModal | 0 | 应用程序强制返回；应用程序一直被挂起，直到用户对消息框作出响应才继续工作 |
| vbSystemModal | 4096 | 系统模式：在用户响应消息框前，所有应用程序都被挂起。 |
| vbMsgBoxHelpButton | 16384 | 将Help按钮添加到消息框 |
| VbMsgBoxSetForeground | 65536 | 指定消息框窗口作为前景窗口 |
| vbMsgBoxRight | 524288 | 文本为右对齐 |
| vbMsgBoxRtlReading | 1048576 | 指定文本应为在希伯来和阿拉伯语系统中的从右到左显示 |
'信息提示框；message box
'MsgBox 函数
'在对话框中显示消息
Sub test()
MsgBox "欢迎学习VBA^_^"
End Sub
'MsgBox(prompt[, buttons] [, title] [, helpfile, context])
'prompt:必需的。字符串表达式，作为显示在对话框中的消息。
'Buttons 可选的。数值表达式是值的总和，指定显示按钮的数目及形式，使用的图标样式，缺省按钮是什么以及消息框的强制回应等。
'Title 可选的。在对话框标题栏中显示的字符串表达式。
'Helpfile 可选的。字符串表达式，识别用来向对话框提供上下文相关帮助的帮助文件。
'Context 可选的。数值表达式，由帮助文件的作者指定给适当的帮助主题的帮助上下文编号。
Sub test2()
MsgBox "欢迎光临我要自学网!" & Chr(13) & "今天是:" & Format(Now, "yyyy-m-d aaaa") _
, , ThisWorkbook.FullName
End Sub
Sub test3()
i = MsgBox("欢迎光临我要自学网!" & Chr(13) & "今天是:" & Format(Now, "yyyy-m-d aaaa") _
, , ThisWorkbook.FullName)
End Sub
Sub test4()
MsgBox "正则表达式学习", vbMsgBoxHelpButton, "欢迎光临我要自学网", ThisWorkbook.Path & "\帮助\正则表达式系统教程.CHM", 0
End Sub
'Buttons:在对话框中显示消息，等待用户单击按钮，
'并返回一个 Integer 告诉用户单击哪一个按钮。
'第一组值 (0–5) 描述了对话框中显示的按钮的类型与数目
Sub 显示按钮的数目及形式()
For i = 0 To 5
MsgBox "Buttons值：" & i, i, "温馨提示^_^"
Next
End Sub
'第二组值 (16, 32, 48, 64) 描述了图标的样式
Sub 图标样式()
For i = 16 To 64 Step 16
MsgBox "图标样式值：" & i, i, "温馨提示^_^"
Next
End Sub
'第三组值 (0, 256, 512,768) 说明哪一个按钮是缺省值
Sub 缺省按钮()
For i = 0 To 768 Step 256
n = n + 1
MsgBox "第" & n & "个按钮是缺省值：" & i, vbMsgBoxHelpButton + 3 + i + 16, "温馨提示^_^"
Next
End Sub
'而第四组值 (0, 4096,16384,65536,524288,1048576) 则决定消息框的强制返回性
Sub 消息框的强制返回性()
arr = Array(Array(0, 4096, 16384, 65536, 524288, 1048576), Array("应用程序强制返回；应用程序一直被挂起，直到用户对消息框作出响应才继续工作。", "系统强制返回；全部应用程序都被挂起，直到用户对消息框作出响应才继续工作。", "将Help按钮添加到消息框", "指定消息框窗口作为前景窗口", "文本为右对齐", "指定文本应为在希伯来和阿拉伯语系统中的从右到左显示"))
For i = 0 To 5
MsgBox arr(1)(i), arr(0)(i), "第" & i + 1 & "个值：" & arr(0)(i)
Next
End Sub
| 按钮 | 值 | 描述 | |
| vbOK | 1 | OK | 确定 |
| vbCancel | 2 | Cancel | 取消 |
| vbAbort | 3 | Abort | 中止 |
| vbRetry | 4 | Retry | 重试 |
| vbIgnore | 5 | Ignore | 忽略 |
| vbYes | 6 | Yes | 是 |
| vbNo | 7 | No | 否 |
Sub test() '获取返回值的方法
i = MsgBox("你好", vbAbortRetryIgnore)
End Sub
Sub 向单元格中录入数据() '实例一
i = Now
j = MsgBox("要将当前日期：" & i & "写入单元格吗？", vbOKCancel)
If j = 1 Then
Cells(1, 1) = i
End If
End Sub
'实例二:sheet3工作表隐藏设置
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Address = "$A$1" Then
i = MsgBox("你真的要隐藏当前工作表吗", vbYesNo + vbInformation)
If i = 6 Then ActiveSheet.Visible = False
End If
End Sub
